有时，您可能想要导出某个 联系人组中的成员。 那么本文就给大家分享2种将群成员提取到Excel的方法。

提供了一项本机功能，允许您导出某个联系人文件夹中的所有联系人。 但是，它不允许您导出联系人组，更不用说提取联系人组中的成员了。 因此，如果您想提取选定联系人组的成员，则需要付出更多的努力。 这里有两个提示，您可以参考。

方法一：通过另存为提取群组成员首先，启动 。然后找到并选择您需要提取其成员的联系人组。接下来，您应该转到“文件”菜单，然后单击“另存为”。随后，在弹出的“另存为”对话框中，选择要保存的目标文件夹，并在“保存类型”下拉列表中选择“纯文本”。然后点击“保存”。

之后，打开 Excel 并创建一个新的 excel 文件。稍后您应该转到“文件”并单击“打开”按钮。在随后出现的“打开”对话框中，首先要进入刚才保存联系人组的文件夹。然后单击“文件名”行中的第二个框，然后从其下拉列表中选择“所有文件”。之后，选择联系人组的文本文件并点击“打开”。

在弹出的“文本导入向导”对话框中，确保选中“分隔符”，然后单击“完成”按钮。

最后你会得到成员，就像下面的截图：

方法二：通过 VBA提取群组成员首先，在 中按“Alt + F11”键按钮。然后在 VBA 编辑器窗口中打开一个新模块。随后，将以下 VBA 代码复制到其中。

Sub ExtractContactGroupMembersToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objMember As Outlook.recipient
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strPath As String
    Dim strFilename As String
 
    Select Case Application.ActiveWindow.Class
           Case olExplorer
                Set objContactGroup = Application.ActiveExplorer.Selection(1)
           Case olInspector
                Set objContactGroup = Application.ActiveInspector.CurrentItem
    End Select
 
    If TypeOf objContactGroup Is DistListItem Then
       'Create a new Excel workbook
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkBook = objExcelApp.Workbooks.Add
       Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
       'Set the two column headers
       objExcelWorkSheet.Cells(1, 1) = "Contact Name"
       objExcelWorkSheet.Cells(1, 2) = "Email Address"
       nRow = 2
 
       'Extract the contact group members' names and email addresses
       For i = 1 To objContactGroup.MemberCount
           Set objMember = objContactGroup.GetMember(i)
           objExcelWorkSheet.Cells(nRow, 1) = objMember.Name
           objExcelWorkSheet.Cells(nRow, 2) = objMember.Address
           nRow = nRow + 1
       Next
 
       'AutoFit the columns in the new Excel worksheet
       objExcelWorkSheet.Columns("A:B").AutoFit
 
       'Change the strPath to your actual case
       strPath = "C:Contact Groups"
       strFilename = strPath & objContactGroup.DLName & ".xlsx"
 
       'Save the Excel workbook
       objExcelWorkBook.Close True, strFilename
 
       'Notify you of the export complete
       MsgBox ("Export Complete!")
    End If
End Sub

之后，您可以像往常一样将宏添加到快速访问工具栏 (QAT)。稍后，您可以选择一个联系人组并单击 QAT 中的宏按钮。

导出后，您将收到一条消息 – “导出完成！”

最终，您可以在VBA代码预先确定的文件夹中找到Excel文件。 打开它，可以看到群成员，如下图：

取回您以前的 PST 数据

由于 容易崩溃，您的 PST 数据可能会在没有任何预兆的情况下损坏。 因此，您应该定期备份 PST 文件。 另外，你最好准备一个强大的工具，比如 ，这可以 修复 数据及时。

作者简介：

Zhang 是一位数据恢复专家 , Inc.，它是数据恢复技术领域的世界领先者，包括 修复sql 和 修复软件产品。 欲了解更多信息，请访问